In diesem Projekt verwendest du Telegram, um bei deinem ESP8266 nachzufragen, wie hoch die aktuelle Temperatur ist. Sobald dein ESP8266 deine Anfrage erhalten hat, fragt er die aktuelle Temperatur beim Sensor BMP180 ab und sendet sie dir auf dein Smartphone.
Dieses Projekt ist der dritte Teil einer Serie und baut auf die Vorgängerprojekte auf. In diesem Artikel findest du alles zum Aufbau und den passenden Sketch; wir besprechen jedoch nicht alle Teile des Codes. Wenn du mehr Details erfahren möchtest, wirf bitte einen Blick in die folgenden Projekte:
- Ein stiller Alarm mit Telegram und einem ESP8266
- Überwache die Temperatur mit Telegram und einem ESP8266
Falls du noch kein Projekt mit Telegram gebaut hast, lerne zunächst, wie du einen Telegram-Bot erstellst.
Anfänger
1 – 2 Stunden
ca. 12 €
Für dieses Projekt benötigst du (Mengen s. Beschreibung):
Der Aufbau des Projekts
Wenn du das Vorgängerprojekt aufgebaut hast, dann musst du auf Seiten der Hardware nichts weiter tun – du kannst deinen Aufbau hier einfach weiterverwenden. 🙂
Im Sketch hat sich dafür einiges verändert:
Der Sketch
___STEADY_PAYWALL___
Kopiere den folgenden Sketch in deine Arduino IDE, ergänze deine Daten und lade ihn auf deinen ESP8266.
/*
Die Temperatur abfragen mit Telegram - polluxlabs.net
*/
//Bibliotheken
#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>
#include <Wire.h>
#include <Adafruit_BMP085.h>
// Deine WLAN-Zugangsdaten
const char* ssid = "NETZWERKNAME";
const char* password = "PASSWORT";
// Den Telegram-Bot initialisieren
#define botToken "TOKEN" // den Bot-Token bekommst du vom Botfather)
//Deine UserID
#define userID "USERID"
WiFiClientSecure client;
UniversalTelegramBot bot(botToken, client);
Adafruit_BMP085 bmp;
//Variable für die Temperatur
float temp;
//Variable für die Anzahl der Anfragen
int numNewRequests;
//Variable für den Text der Anfrage, die du sendest
String text = "";
//UserID des Absenders
String chat_id = "";
//Name des Absenders
String from_name = "";
//Variable für die Willkommensnachricht
String welcome = "";
//Funktion fürs Verarbeiten neuer Anfragen
void handleNewRequests(int numNewRequests) {
for (int i = 0; i < numNewRequests; i++) { //loopt durch die neuen Anfragen
//Checkt, ob du die Anfrage gesendet hast oder jemand anderes
chat_id = String(bot.messages[i].chat_id);
if (chat_id != userID) {
bot.sendMessage(chat_id, "Du bist nicht autorisiert!", "");
continue;
}
// Anfragetext speichern
text = bot.messages[i].text;
Serial.println(text);
from_name = bot.messages[i].from_name;
if (text == "/start") {
welcome = "Willkommen, " + from_name + ".\n";
welcome += "Mit folgendem Befehl fragst du die aktuelle Temperatur ab: \n\n";
welcome += "/messen \n";
bot.sendMessage(chat_id, welcome, "");
bot.sendMessage(chat_id, "http://gph.is/2aLXZ8H", "");
}
if (text == "/messen") {
temp = bmp.readTemperature();
bot.sendMessage(chat_id, "Temperatur: " + String(temp) + " ºC", "");
}
}
}
void setup() {
Serial.begin(115200);
client.setInsecure();
//Verbindung zum WLAN
Serial.print("Verbinde mich mit: ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println("");
Serial.println("Verbunden!");
if (!bmp.begin()) {
Serial.println("Kein Sensor gefunden! Checke die Verbindung.");
while (1) {}
}
}
void loop() {
//checkt, ob eine neue Anfrage reinkam
int numNewRequests = bot.getUpdates(bot.last_message_received + 1);
while (numNewRequests) { //wird ausgeführt, wenn numNewRequests == 1
Serial.println("Anfrage erhalten");
handleNewRequests(numNewRequests);
numNewRequests = bot.getUpdates(bot.last_message_received + 1);
}
delay(1000);
}Was ist neu in diesem Sketch?
In diesem Sketch läuft einiges anders: In den zwei vorangegangenen Projekten hat dein ESP8266 nur Nachrichten gesendet, in diesem Projekt wartet er jedoch auf eine Nachricht von dir – die er dann selbst mit der aktuellen Temperatur beantwortet.
Dafür muss dein ESP8266 – im Gegensatz zu den vorherigen Projekten – die ganze Zeit mit deinem WLAN verbunden sein. Deshalb wandert der Code, mit dem du die Verbindung herstellst, direkt in die Setup-Funktion:
Serial.print("Verbinde mich mit: ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println("");
Serial.println("Verbunden!");Schauen wir jetzt direkt in den Loop. Dort prüft dein ESP8266 alle 1000 Millisekunden, ob eine neue Anfrage vorliegt:
int numNewRequests = bot.getUpdates(bot.last_message_received + 1);Wenn das der Fall ist, wird in der Variablen numNewRequests mithilfe der Funktion bot.getUpdates() die Anzahl der vorliegenden Anfragen gespeichert (im Normalfall eine 1, aber es können theoretisch ja auch mehrere vorliegen).
Das wiederum setzt den folgenden While-Loop in Gang, der die Funktion handleNewRequests() so oft aufruft wie Anfragen “abzuarbeiten” sind. In diesem Loop wird auch die Variable numNewRequests aktualisiert – sobald hier wieder eine 0 enthalten ist, endet der Loop.
while (numNewRequests) {
handleNewRequests(numNewRequests);
numNewRequests = bot.getUpdates(bot.last_message_received + 1);
}Die Funktion handleNewRequests()
Kommen wir zum Kernstück des Sketchs. Diese Funktion handleNewRequests() erwartet bei Ihrem Aufruf ein Argument – nämlich die Anzahl der vorliegenden Anfragen, die in der Variablen numNewRequests steckt. Diese hast du beim Aufruf der Funktion im While-Lopp bereits mitgegeben:
handleNewRequests(numNewRequests);Bei der Deklaration der Funktion taucht diese Variable wieder auf, um dann gleich weiterverarbeitet zu werden. Diesmal iterierst du mit einem For-Loop über die Anzahl der Anfragen, um sie eine nach der anderen abzuarbeiten:
void handleNewRequests(int numNewRequests) {
for (int i = 0; i < numNewRequests; i++) { Innerhalb des Loops findet zuerst eine sehr wichtige Prüfung statt – nämlich ob die Anfrage überhaupt von einem autorisierten User (also von dir) stammt. Hierfür speicherst du die chat_id, die mit jeder Anfrage übergeben wird, in der gleichnamigen Variablen.
Anschließend prüfst du, ob diese mit deiner eigenen UserID übereinstimmt. Ist das nicht der Fall, erhält der Absender eine entsprechende Nachricht und der For-Loop wird mit continue abgebrochen:
chat_id = String(bot.messages[i].chat_id);
if (chat_id != userID) {
bot.sendMessage(chat_id, "Du bist nicht autorisiert!", "");
continue;
}Wenn die Anfrage jedoch von dir stammt, speicherst du ihren Textinhalt und den Namen des Absenders (also wiederum deinen) ab:
text = bot.messages[i].text;
from_name = bot.messages[i].from_name;Fehlen nur noch zwei If-Statements. Wenn du deinen Telegram-Bot zum ersten Mal startest, machst du das mit dem Text /start (den du natürlich auch senden kannst, wenn der Bot schon läuft). In diesem Fall erscheint eine kleine Begrüßungsnachricht mit einer Erklärung: Um die aktuelle Temperatur abzufragen, musst du deinem Bot (und damit deinem ESP8266) die Nachricht /messen schicken.
Hier werden wieder Strings miteinander verbunden, diesmal mit dem Operator +=, der einfach die Variable welcome um weiteren Text erweitert. Auch beachtenswert: Mit \n kannst du einen Zeilenumbruch einfügen.
Am Ende des Statements findest du wieder die Funktion bot.sendMessage(), die du bereits kennengelernt hast. Diese taucht hier gleich zweimal auf: Einmal, um den String welcome zu senden und dann noch einmal, um ein GIF hinterherzuschicken. Wenn du spaßeshalber auch GIFs senden möchtest, reicht dafür einfach die entsprechende URL der Datei.
if (text == "/start") {
welcome = "Willkommen, " + from_name + ".\n";
welcome += "Mit folgendem Befehl fragst du die aktuelle Temperatur ab: \n\n";
welcome += "/messen \n";
bot.sendMessage(chat_id, welcome, "");
bot.sendMessage(chat_id, "http://gph.is/2aLXZ8H", "");
}Die zweite Abfrage kümmert sich um die Anfrage /messen, die mit der aktuellen Temperatur beantwortet werden soll. Auch das kennst du bereits aus den vorangegangenen Projekten:
if (text == "/messen") {
temp = bmp.readTemperature();
bot.sendMessage(chat_id, "Temperatur: " + String(temp) + " ºC", "");
}Und das war es auch schon. Du hast in dieser Lektion gelernt, wie du nicht nur Nachrichten von deinem ESP8266 an deinen Telegram-Bot senden kannst, sondern auch von dort aus Sensordaten abrufen kannst.
Wie geht es weiter?
Du kannst natürlich nicht nur die Temperatur abfragen. Der Sensor BMP180 kann auch den Luftdruck ermitteln. Der Nachfolger BMP280 misst sogar die Luftfeuchtigkeit. Baue z.B. eine Wetterstation, bei der du die aktuellen Daten aus der Ferne abfragst.
Eine weitere Möglichkeit ist ein Feuchtigkeitssensor, den du neben eine Pflanze in die Erde steckst. Wenn du denkst, die Erde sei zu trocken, kannst du eine automatische “Gießkanne” von deinem Smartphone aus steuern.
Letzte Aktualisierung am 26.04.2024 / Affiliate Links / Bilder von der Amazon Product Advertising API
